TITLE 'ICATS IGNORE-THIS-COMMAND ROUTINE' IGN00010
*********************************************************************** IGN00020
* * IGN00030
* MODULE NAME = IGNORCMD * IGN00040
* * IGN00050
* FUNCTION = IGNORE THIS ICATS REQUEST. IF FROM THE CONSOLE OR * IGN00060
* A SMSG, DO NOTHING. IF FROM A UTS MACHINE, ECHO * IGN00070
* BACK HIS REQUEST CONTROL BLOCK WITH A ZERO RETURN * IGN00080
* CODE. * IGN00090
* * IGN00100
* ENTRY POINTS = IGNORCMD * IGN00110
* * IGN00120
* LINKAGE = BALR R14,R15 FROM ICATS MAINLINE. * IGN00130
* * IGN00140
* REGISTER CONTENTS UPON ENTRY = * IGN00150
* R2 = POINTS TO THE ICATS COMMON DATA AREA, AS ALWAYS. * IGN00160
* R14 = RETURN ADDRESS BACK TO ICATS MAINLINE * IGN00170
* R15 = ENTRY POINT TO THIS MODULE * IGN00180
* * IGN00190
* REGISTER USAGE = * IGN00200
* R0-R1 = USED TO PASS PARAMETERS TO SUBROUTINES. * IGN00210
* R2 = USED TO ADDRESS THE ICATS COMMON DATA AREA. * IGN00220
* R3-R10 = FREE * IGN00230
* R11 = MY BASE REGISTER (X'2C000') * IGN00240
* R12-R13 = FREE * IGN00250
* R14 = MY RETURN ADDRESS WHEN I CALL SOMEBODY * IGN00260
* R15 = SUBROUTINE ADDRESS * IGN00270
* * IGN00280
* MODULE LOGIC: * IGN00290
* 1) IF THIS REQUEST CAME FROM THE CONSOLE OR A SMSG, * IGN00300
* DO NOTHING. JUST RETURN BACK TO THE DISPATCHER. * IGN00310
* 2) ELSE THIS IS FROM A UTS MACHINE. SET THE * IGN00320
* RETURN CODE AND THE BYTE COUNT TO 0 AND ECHO * IGN00330
* HIS REQUEST CONTROL BLOCK BACK TO THE UTS MACHINE. * IGN00340
* * IGN00350
* NORMAL EXIT = * IGN00360
* R15 = 0 * IGN00370
* * IGN00380
* EXTERNAL REFERENCES = NONE * IGN00390
* * IGN00400
* CONTROL BLOCKS = ICDATA (ICATS COMMON DATA AREA) * IGN00410
* * IGN00420
* NON-STANDARD MACROS (FOUND IN ICATS MACLIB) * IGN00430
* ICDATA = ICATS COMMON DATA AREA DSECT. * IGN00440
* ETTE = ENTER TRACE TABLE ENTRY SUBROUTINE * IGN00450
* * IGN00460
* CHANGE ACTIVITY * IGN00470
* DATE NAME REASON FOR CHANGE * IGN00480
* 04/19/83 RICK JASPER BROKEN AWAY FROM ICATS MAINLINE INTO * IGN00490
* SEPARATE SUBROUTINE * IGN00500
* * IGN00510
*********************************************************************** IGN00520
PRINT GEN,NODATA IGN00530
IGNORCMD CSECT IGN00540
USING ICDATA,R2 ADDRESS ICATS COMMON DATA AREA IGN00550
USING *,R15 USE R15 FOR BASE REG NEXT INSTRUCTION ONLY IGN00560
STM R0,R14,REGSAVE SAVE CALLER'S REGISTERS IGN00570
DROP R15 IGN00580
USING IGNORCMD,R11 R11 WILL BE BASE REGISTER IGN00590
LR R11,R15 ESTABLISH BASE REGISTER IGN00600
*-------------------------------------------------------------* IGN00610
* SEE WHO GAVE ME THIS COMMAND I'M TO IGNORE * IGN00620
*-------------------------------------------------------------* IGN00630
TM FLAGB,UTSCMD DID THIS COMMAND COME FROM A UTS ?? IGN00640
BNO IGBYE MUST HAVE BEEN FROM CONSOLE OR SMSG IGN00650
XC PARM15,PARM15 ZERO RETURN CODE AND DATA LENGTH IGN00660
LA R0,128 REPLY CONTROL BLOCK = 128 BYTES BIG IGN00670
L R1,PARM0 POINT TO START OF REPLY CONTROL BLOCK IGN00680
L R15,AWRITUTS IGN00690
BALR R14,R15 GO GIVE THE REPLY TO THE UTS MACHINE IGN00700
* IGNORE ANY ERRORS. IGN00710
IGBYE EQU * IGN00720
LM R0,R14,REGSAVE RESTORE CALLER'S REGISTERS IGN00730
BR R14 I'M DONE HERE IGN00740
REGSAVE DS 15F READ ROUTINE SAVE AREA IGN00750
LTORG IGN00760
ICDATA IGN00770
END IGN00780