A                                      DSPSIZ(24 80 *DS3)
     A          R DUMMY                     ASSUME
     A                                  1  2' '
     A          R FOOT
     A                                 23  2'Press ATTN key for choices.'
     A                                      COLOR(BLU)
     A          R SFL                       SFL
     A            JOBNAM        10A  O  8  2
     A            JOBUSR        10A  O  8 13
     A            JOBNBR         6A  O  8 24
     A            JOBPTY         3A  O  8 31
     A            JOBIOT         5Y 0O  8 35EDTCDE(3)
     A            JOBSEC         5Y 2O  8 41EDTCDE(3)
     A            JOBGPH        30A  O  8 50DSPATR(RI)
     A  50N51                               DSPATR(HI)
     A  51                                  DSPATR(BL)
     A          R SFLCTL                    SFLCTL(SFL)
     A                                      SFLSIZ(0014)
     A                                      SFLPAG(0014)
     A  90                                  SFLDSP
     A  91                                  SFLDSPCTL
     A  92                                  SFLCLR
     A                                      FRCDTA
     A                                      OVERLAY
     A  52                                  ALARM
     A                                  1 31'CPU Activity Monitor'
     A                                      DSPATR(HI)
     A                                  1 71DATE
     A                                      EDTCDE(Y)
     A                                  2 71TIME
     A                                  3  2'Elapsed time - :'
     A            ELPSEC         5Y 2O  3 21EDTCDE(3)
     A                                  3 28'Seconds'
     A                                  4  2'CPU Utilisation:'
     A            CPUSEC         5Y 2O  4 21EDTCDE(3)
     A                                  4 28'Seconds'
     A            CPUPCT         5Y 2O  4 39EDTCDE(3)
     A                                  4 46'%'
     A            CPUGPH        30A     4 50DSPATR(RI)
     A  60                                  COLOR(GRN)
     A  61                                  COLOR(YLW)
     A  62                                  COLOR(RED)
     A                                  6  2'Job or'
     A                                      DSPATR(HI)
     A                                  6 35'Total'
     A                                      DSPATR(HI)
     A                                  7  3'Task'
     A                                      DSPATR(HI)
     A                                  7 13'User'
     A                                      DSPATR(HI)
     A                                  7 24'Number'
     A                                      DSPATR(HI)
     A                                  7 36'I/O'
     A                                      DSPATR(HI)
     A                                  7 31'Pty.'
     A                                      DSPATR(HI)
     A                                  7 50'Share of CPU utilisation'
     A                                      DSPATR(HI)
     A                                  6 44'CPU'
     A                                      DSPATR(HI)
     A                                  7 43'Secs'
     A                                      DSPATR(HI)
     A          R CHCWDW                    WINDOW(9 2 11 32 *NOMSGLIN)
     A                                      WDWBORDER((*DSPATR RI) +
     A                                                (*COLOR BLU) +
     A                                                (*CHAR '        '))
     A            CHOICE         2Y 0B  2  2SNGCHCFLD
     A                                      CHOICE(2  '>Change top job')
     A                                      CHOICE(3  '>Hold top job')
     A                                      CHOICE(4  '>End top job')
     A                                      CHOICE(5  '>Display top job')
     A                                      CHOICE(90 '>SIGN-OFF')
     A                                  9  2'Press ENTER to resume Monitor.'
     A                                      COLOR(BLU)